controls/cf_agent.cf

Table of Contents

This is where body agent control is defined. body agent control is where various settings related to cf-agent can be tuned.

agent bodies

control

Prototype: control

Implementation:

body agent control
{
      # Global default for time that must elapse before promise will be rechecked.
      # Don't keep any promises.

    any::

      # Minimum time (in minutes) which should have passed since the last time
      # the promise was verified before it is checked again.

      ifelapsed => "1";

      # Do not send IP/name during server connection if address resolution is broken.
      # Comment it out if you do NOT have a problem with DNS

      skipidentify => "true";

      # explicitly not supported (but they should break long before)
      abortclasses => { "cfengine_3_3", "cfengine_3_4", @(def.control_agent_abortclasses) };

      # The abortbundleclasses slist contains regular expressions that match
      # classes which if defined lead to termination of current bundle.
      abortbundleclasses => { @(def.control_agent_abortbundleclasses) };

      # Maximum number of outgoing connections to a remote cf-serverd.
      maxconnections => "$(def.control_agent_maxconnections)";

    _have_control_agent_files_single_copy::
      # CFE-3622

      # File patterns which allow a file to be copied over only a single time
      # per agent run.

      files_single_copy => { @(def.control_agent_files_single_copy) };

    mpf_control_agent_default_repository::

      # Location to backup files before they are edited by cfengine

      default_repository => "$(def.control_agent_default_repository)";

      # Environment variables based on Distro

    debian::

      environment => { @(def.environment_vars) };

}